# General .login file 
# This file is called .login on d0mino, clued0, afs
# ---------------------------------------------------------------------
# Use hostname dependant options for different machines.
# ---------------------------------------------------------------------
# First of all find out which machine is being used.
# ---------------------------------------------------------------------
set CPU=`uname -n`
if ( `uname -n | awk '{print substr($1,1,6)}'` == 'd0mino' ) then
   setenv ALS_CLUSTER d0mino
   setenv CPUOS   irix
   if ( -r /usr/local/etc/fermi.cshrc ) source /usr/local/etc/fermi.cshrc
else if ( `uname -n | awk '{i=length($1); print substr($1,i-5,6)}'` == 'clued0') then
   setenv ALS_CLUSTER clued0
   setenv CPUOS   linux
else if ( `uname -n | awk '{print substr($1,1,4)}'` == 'd0cs' ) then
   setenv ALS_CLUSTER cab
   setenv CPUOS   linux
else if ( `uname -n | awk '{print substr($1,1,5)}'` == 'cmswn' ) then
   setenv ALS_CLUSTER cmsuaf
   setenv CPUOS   linux
else if ( `uname -n | awk '{print substr($1,1,5)}'` == 'lpcdt' ) then
   setenv ALS_CLUSTER lpc
   setenv CPUOS   linux
else if ( `uname -n | awk '{print substr($1,1,4)}'` == 'flxi' ) then
   setenv ALS_CLUSTER flxi
   setenv CPUOS   linux
else if ( `uname -n | awk '{print substr($1,1,4)}'` == 'fsui' ) then
   setenv ALS_CLUSTER fsui
   setenv CPUOS   sun
else 
   setenv ALS_CLUSTER unknown
   setenv CPUOS   unknown
endif
# ---------------------------------------------------------------------
# d0mino specific: execute fermi.login
# ---------------------------------------------------------------------
if ( $ALS_CLUSTER == 'd0mino' ) then
   if ( -r /usr/local/etc/fermi.login ) source /usr/local/etc/fermi.login
endif
# ---------------------------------------------------------------------
# clued0 specific:
# ---------------------------------------------------------------------
if ( $ALS_CLUSTER == 'clued0' ) then
   if ( -r .fermi.login ) source .fermi.login
endif
# ---------------------------------------------------------------------
# flxi specific:
# ---------------------------------------------------------------------
if ( $ALS_CLUSTER == 'flxi' ) then
   if ( -r .fermi.login ) source .fermi.login
endif
# ---------------------------------------------------------------------
# flxi specific:
# ---------------------------------------------------------------------
if ( $ALS_CLUSTER == 'fsui' ) then
   if ( -r .fermi.login ) source .fermi.login
endif
# ---------------------------------------------------------------------
# general: skip the rest of the .login file for batch sessions
# ---------------------------------------------------------------------
if ( $?ENVIRONMENT ) then
   if ( $ENVIRONMENT == "BATCH" ) exit
endif
if ( $?prompt == 0 || $?USER == 0 ) exit
# ---------------------------------------------------------------------
# general: only for interactive sessions
# ---------------------------------------------------------------------
unset noclobber
unset ignoreeof
#eval `resize -c`
date '+Interactive session starts on %A, %d %B at %H:%M'
if ( $?DISPLAY) then
   echo 'Connecting to X server' $DISPLAY
endif